/*More changes than you can shake a stick at.
*/

void (entity targ, entity inflictor, entity attacker, float damage) T_Damage;
void () player_run;
void(entity bomb, entity attacker, float rad, entity ignore) T_RadiusDamage;
void(vector org, vector vel, float damage) SpawnBlood;
void() SuperDamageSound;
void(string gibname, float dm) ThrowGib; //For explosions
void(vector org,vector dir) eject_shell; //For shell ejection
void() feign;   // feign death
.string oldweaponmodel; // feign death
.float oldweapon; // feign death
void() W_ThrowAxe; //thrown axes
void() player_tax1; //thrown axes

// called by worldspawn
void() W_Precache =
{
        precache_model ("progs/throwaxe.mdl");  // thrown axe model
        precache_sound ("weapons/woosh.wav");  // WOOSH sound for throwing axe
        precache_sound ("weapons/taxhit.wav");  // new ax hit sound (FROM QTEST)
        precache_sound ("weapons/r_exp3.wav");  // new rocket explosion
	precache_sound ("weapons/rocket1i.wav");	// spike gun
	precache_sound ("weapons/sgun1.wav");
	precache_sound ("weapons/shellhit.wav"); //Shell ejection
	precache_sound ("weapons/guncock.wav");	// player shotgun
	precache_sound ("weapons/ric1.wav");	// ricochet (used in c code)
	precache_sound ("weapons/ric2.wav");	// ricochet (used in c code)
	precache_sound ("weapons/ric3.wav");	// ricochet (used in c code)
	precache_sound ("weapons/spike2.wav");	// super spikes
	precache_sound ("weapons/tink1.wav");	// spikes tink (used in c code)
	precache_sound ("weapons/grenade.wav");	// grenade launcher
	precache_sound ("weapons/bounce.wav");		// grenade bounce
      precache_model ("progs/h_demon.mdl");
      precache_model ("progs/h_dog.mdl");
      precache_model ("progs/laser.mdl");
      precache_model ("progs/shelcase.mdl"); //Shell ejection
      precache_sound ("enforcer/enfire.wav"); // player shotgun
	precache_sound ("weapons/shotgn2.wav");	// super shotgun
      precache_sound ("zombie/z_hit.wav");
};

float camera_on;  //Use this variable to determine if the HOLOGRAM camera
                  //is ON or OFF.  This is important because if the player
                  //detonates the HOLOGRAM while the camera is on...then
                  //all sorts of funky things happen with the camera view!

float() crandom =
{
	return 2*(random() - 0.5);
};


/*My more than a little poorly written recoil code, but it seems
pretty good to me.
*/

void(entity attacker, float recoil_val) Recoil =
{
        local float friction,gravity;
        local vector dir,friction_vec;

        dir = aim(attacker,recoil_val);
        dir = normalize (dir);
        recoil_val =  -10*recoil_val;
        gravity = cvar ("SV_GRAVITY");
        friction_vec = gravity * '0 0 1';
        if (self.flags & FL_ONGROUND)
        {
                friction = cvar ("SV_FRICTION");
                friction_vec = friction * dir + friction_vec;
        }
        attacker.velocity = recoil_val * dir + attacker.velocity + friction_vec;
};

/*
================
W_FireAxe
================
*/
void() W_FireAxe =
{
	local	vector	source;
	local	vector	org;

	source = self.origin + '0 0 16';
	traceline (source, source + v_forward*64, FALSE, self);
	if (trace_fraction == 1.0)
		return;
	
	org = trace_endpos - v_forward*4;

	if (trace_ent.takedamage)
	{
		trace_ent.axhitme = 1;
		SpawnBlood (org, '0 0 0', 20);
//For the special flesh hitting sound.
		sound (self, CHAN_WEAPON, "zombie/z_hit.wav", 1, ATTN_NORM);
		T_Damage (trace_ent, self, self, 20);
	}
	else
	{	// hit wall
		sound (self, CHAN_WEAPON, "player/axhit2.wav", 1, ATTN_NORM);
		WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
		WriteByte (MSG_BROADCAST, TE_GUNSHOT);
		WriteCoord (MSG_BROADCAST, org_x);
		WriteCoord (MSG_BROADCAST, org_y);
		WriteCoord (MSG_BROADCAST, org_z);
	}
};


//============================================================================


vector() wall_velocity =
{
	local vector	vel;
	
	vel = normalize (self.velocity);
	vel = normalize(vel + v_up*(random()- 0.5) + v_right*(random()- 0.5));
	vel = vel + 2*trace_plane_normal;
	vel = vel * 200;
	
	return vel;
};


/*
================
SpawnMeatSpray
================
*/
void(vector org, vector vel) SpawnMeatSpray =
{
	local	entity missile, mpuff;
	local	vector	org;

	missile = spawn ();
	missile.owner = self;
	missile.movetype = MOVETYPE_BOUNCE;
	missile.solid = SOLID_NOT;

	makevectors (self.angles);

	missile.velocity = vel;
	missile.velocity_z = missile.velocity_z + 250 + 50*random();

	missile.avelocity = '3000 1000 2000';
	
// set missile duration
	missile.nextthink = time + 1;
	missile.think = SUB_Remove;

	setmodel (missile, "progs/zom_gib.mdl");
	setsize (missile, '0 0 0', '0 0 0');		
	setorigin (missile, org);
};

/*
================
SpawnBlood      Added more blood, more blood more blood
================
*/
void(vector org, vector vel, float damage) SpawnBlood =
{
	particle (org, vel*0.1, 73, damage*2);
        particle (org, vel*0.2, 73, damage*4);
        particle (org, vel*0.3, 73, damage*8);
        particle (org, vel*0.4, 73, damage*16);
};

/*
================
spawn_touchblood        And more blood
================
*/
void(float damage) spawn_touchblood =
{
	local vector	vel;

	vel = wall_velocity () * 0.2;
	SpawnBlood (self.origin + vel*0.01, vel, damage);
        SpawnBlood (self.origin + vel*0.04, vel, damage+15);
};


/*
================
SpawnChunk      Mmmmm, chunky
================
*/
void(vector org, vector vel) SpawnChunk =
{
	particle (org, vel*0.02, 0, 10);
        particle (org, vel*0.05, 0, 40);
};

/*
==============================================================================

MULTI-DAMAGE

Collects multiple small damages into a single damage

==============================================================================
*/

entity	multi_ent;
float	multi_damage;

void() ClearMultiDamage =
{
	multi_ent = world;
	multi_damage = 0;
};

void() ApplyMultiDamage =
{
	if (!multi_ent)
		return;
	T_Damage (multi_ent, self, self, multi_damage);
};

void(entity hit, float damage) AddMultiDamage =
{
	if (!hit)
		return;
	
	if (hit != multi_ent)
	{
		ApplyMultiDamage ();
		multi_damage = damage;
		multi_ent = hit;
	}
	else
		multi_damage = multi_damage + damage;
};

/*
==============================================================================

BULLETS

==============================================================================
*/

/*
================
TraceAttack
================
*/
void(float damage, vector dir) TraceAttack =
{
	local	vector	vel, org;
	
	vel = normalize(dir + v_up*crandom() + v_right*crandom());
	vel = vel + 2*trace_plane_normal;
	vel = vel * 200;

	org = trace_endpos - dir*4;

	if (trace_ent.takedamage)
	{
		SpawnBlood (org, vel*0.2, damage);
		AddMultiDamage (trace_ent, damage);
	}
	else
	{
		WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
		WriteByte (MSG_BROADCAST, TE_GUNSHOT);
		WriteCoord (MSG_BROADCAST, org_x);
		WriteCoord (MSG_BROADCAST, org_y);
		WriteCoord (MSG_BROADCAST, org_z);
	}
};

/*
================
FireBullets

Used by shotgun, super shotgun, and enemy soldier firing
Go to the trouble of combining multiple pellets into a single damage call.
================
*/
void(float shotcount, vector dir, vector spread) FireBullets =
{
	local	vector direction;
	local	vector	src;
	
	makevectors(self.v_angle);

	src = self.origin + v_forward*10;
	src_z = self.absmin_z + self.size_z * 0.7;

	ClearMultiDamage ();
	while (shotcount > 0)
	{
		direction = dir + crandom()*spread_x*v_right + crandom()*spread_y*v_up;

		traceline (src, src + direction*2048, FALSE, self);
		if (trace_fraction != 1.0)
			TraceAttack (4, direction);

		shotcount = shotcount - 1;
	}
	ApplyMultiDamage ();
};

/*
================
W_FireShotgun           As can be seen here, I have replaced this with
                        a laser blaster (even though it still uses
                        shotgun ammo).  It actually makes it a bit
                        worthwhile to use.  Imagine that.
================
*/
void() Laser_Touch_P =
{
	local vector org;
	
	if (other == self.owner)
		return;		// don't explode on owner

	if (pointcontents(self.origin) == CONTENT_SKY)
	{
		remove(self);
		return;
	}
	
	org = self.origin - 8*normalize(self.velocity);

	if (other.health)
	{
		SpawnBlood (org, self.velocity*0.2, 15);
		T_Damage (other, self, self.owner, 15);
	}
	else
	{
		WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
                WriteByte (MSG_BROADCAST,  TE_KNIGHTSPIKE);
		WriteCoord (MSG_BROADCAST, org_x);
		WriteCoord (MSG_BROADCAST, org_y);
		WriteCoord (MSG_BROADCAST, org_z);
	}
	remove(self);	
};

void(vector org, vector dir) Launch_Laser =
{
        sound (self, CHAN_WEAPON, "enforcer/enfire.wav", 1, ATTN_NORM);
	newmis = spawn();
	newmis.owner = self;
        newmis.movetype = MOVETYPE_FLYMISSILE;
        newmis.solid = SOLID_BBOX;
	newmis.effects = EF_DIMLIGHT;
        newmis.velocity = dir * 1800;
	newmis.angles = vectoangles(newmis.velocity);
        newmis.touch = Laser_Touch_P;
        newmis.nextthink = time + 6;
	newmis.think = SUB_Remove;
	setmodel (newmis, "progs/laser.mdl");
	setsize (newmis, '0 0 0', '0 0 0');		
        setorigin (newmis, org);
};



void() W_FireShotgun =
{
        local vector org,dir;
        
       self.currentammo = self.ammo_shells = self.ammo_shells - 1;
	 self.effects = self.effects | EF_MUZZLEFLASH;
       self.attack_finished = time + 0.5;
       makevectors (self.v_angle);
       org = self.origin + v_forward * 7.5 + '0 0 16';
       dir = aim (self, 1800);
       Launch_Laser(org, dir);
	 self.punchangle_x = -2;
       Recoil (self,3); // Not too much recoil
       eject_shell (self.origin + '0 0 16' + v_forward*3,dir); //eject shell
};

/*
================
W_FireSuperShotgun
================
*/
void() W_FireSuperShotgun =
{
	local vector dir;

	if (self.currentammo == 1)
	{
		W_FireShotgun ();
		return;
	}
		
	sound (self ,CHAN_WEAPON, "weapons/shotgn2.wav", 1, ATTN_NORM);	

	self.punchangle_x = -4;
	self.currentammo = self.ammo_shells = self.ammo_shells - 2;
	dir = aim (self, 100000);
	FireBullets (14, dir, '0.14 0.08 0');
      Recoil (self,10);
      eject_shell (self.origin + '0 0 16' + v_forward*3,dir); //eject shell
      eject_shell (self.origin + '0 0 16' + v_forward*3,dir);

};


/*
==============================================================================

ROCKETS

==============================================================================
*/

void()	s_explode1	=	[0,		s_explode2] {};
void()	s_explode2	=	[1,		s_explode3] {};
void()	s_explode3	=	[2,		s_explode4] {};
void()	s_explode4	=	[3,		s_explode5] {};
void()	s_explode5	=	[4,		s_explode6] {};
void()	s_explode6	=	[5,		SUB_Remove] {};

void() BecomeExplosion =
{
	self.movetype = MOVETYPE_NONE;
	self.solid = SOLID_NOT;
        ThrowGib ("progs/zom_gib.mdl", -500);
        ThrowGib ("progs/zom_gib.mdl", -250);
        ThrowGib ("progs/zom_gib.mdl", -50);
        ThrowGib ("progs/zom_gib.mdl", -25);
        if ( !(self.velocity = '0 0 0') ) // And Blood too
        {
                SpawnBlood (self.origin,self.velocity,500);
                SpawnBlood (self.origin,-1*self.velocity,500);
                self.velocity = '0 0 0';
        }
        else
        {
                SpawnBlood (self.origin,'0 0 100',500);
                SpawnBlood (self.origin,'0 100 0',500);
                SpawnBlood (self.origin,'0 -100 0',500);
                SpawnBlood (self.origin,'-100 0 0',500);
        }
	self.touch = SUB_Null;
        setmodel (self, "progs/s_explod.spr");  //A little fire goes a long way
        s_explode1 ();
};

void() T_MissileTouch =
{
	local float	damg;

	if (other == self.owner)
		return;		// don't explode on owner

	if (pointcontents(self.origin) == CONTENT_SKY)
	{
		remove(self);
		return;
	}

	damg = 100 + random()*20;
	
	if (other.health)
	{
		if (other.classname == "monster_shambler")
			damg = damg * 0.5;	// mostly immune
		T_Damage (other, self, self.owner, damg );
	}

	// don't do radius damage to the other, because all the damage
	// was done in the impact
	T_RadiusDamage (self, self.owner, 120, other);

//	sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
	self.origin = self.origin - 8*normalize(self.velocity);

// Damned sparks again
//        WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
//        WriteByte (MSG_BROADCAST, TE_EXPLOSION);
//        WriteCoord (MSG_BROADCAST, self.origin_x);
//        WriteCoord (MSG_BROADCAST, self.origin_y);
//        WriteCoord (MSG_BROADCAST, self.origin_z);

	BecomeExplosion ();
};



/*
================
W_FireRocket
================
*/
void() W_FireRocket =
{
	local	entity missile, mpuff;
	
	self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
	
	sound (self, CHAN_WEAPON, "weapons/sgun1.wav", 1, ATTN_NORM);

	self.punchangle_x = -2;

	missile = spawn ();
	missile.owner = self;
	missile.movetype = MOVETYPE_FLYMISSILE;
	missile.solid = SOLID_BBOX;
		
// set missile speed	

	makevectors (self.v_angle);
        missile.velocity = aim(self, 1500);
        missile.velocity = missile.velocity * 1500;
	missile.angles = vectoangles(missile.velocity);
	
	missile.touch = T_MissileTouch;
	
// set missile duration
	missile.nextthink = time + 5;
	missile.think = SUB_Remove;

//Is that a demon's head?!?
        setmodel (missile, "progs/h_demon.mdl");
        setsize (missile, '0 0 0', '0 0 0');     
	setorigin (missile, self.origin + v_forward*8 + '0 0 16');
        Recoil (self,20);       //Now that is some kick
};

/*
===============================================================================

LIGHTNING

===============================================================================
*/

/*
=================
LightningDamage
=================
*/
void(vector p1, vector p2, entity from, float damage) LightningDamage =
{
	local entity		e1, e2;
	local vector		f;
	
	f = p2 - p1;
	normalize (f);
	f_x = 0 - f_y;
	f_y = f_x;
	f_z = 0;
	f = f*16;

	e1 = e2 = world;

	traceline (p1, p2, FALSE, self);
	if (trace_ent.takedamage)
	{
		particle (trace_endpos, '0 0 100', 225, damage*4);
		T_Damage (trace_ent, from, from, damage);
		if (self.classname == "player")
		{
			if (other.classname == "player")
				trace_ent.velocity_z = trace_ent.velocity_z + 400;
		}
	}
	e1 = trace_ent;

	traceline (p1 + f, p2 + f, FALSE, self);
	if (trace_ent != e1 && trace_ent.takedamage)
	{
		particle (trace_endpos, '0 0 100', 225, damage*4);
		T_Damage (trace_ent, from, from, damage);
	}
	e2 = trace_ent;

	traceline (p1 - f, p2 - f, FALSE, self);
	if (trace_ent != e1 && trace_ent != e2 && trace_ent.takedamage)
	{
		particle (trace_endpos, '0 0 100', 225, damage*4);
		T_Damage (trace_ent, from, from, damage);
	}
};


void() W_FireLightning =
{
	local	vector		org;

	if (self.ammo_cells < 1)
	{
		self.weapon = W_BestWeapon ();
		W_SetCurrentAmmo ();
		return;
	}

// explode if under water
	if (self.waterlevel > 1)
	{
		T_RadiusDamage (self, self, 35*self.ammo_cells, world);
		self.ammo_cells = 0;
		W_SetCurrentAmmo ();
		return;
	}

	if (self.t_width < time)
	{
		sound (self, CHAN_WEAPON, "weapons/lhit.wav", 1, ATTN_NORM);
		self.t_width = time + 0.6;
	}
	self.punchangle_x = -2;

	self.currentammo = self.ammo_cells = self.ammo_cells - 1;

	org = self.origin + '0 0 16';
	
	traceline (org, org + v_forward*600, TRUE, self);

	WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
	WriteByte (MSG_BROADCAST, TE_LIGHTNING2);
	WriteEntity (MSG_BROADCAST, self);
	WriteCoord (MSG_BROADCAST, org_x);
	WriteCoord (MSG_BROADCAST, org_y);
	WriteCoord (MSG_BROADCAST, org_z);
	WriteCoord (MSG_BROADCAST, trace_endpos_x);
	WriteCoord (MSG_BROADCAST, trace_endpos_y);
	WriteCoord (MSG_BROADCAST, trace_endpos_z);

	LightningDamage (self.origin, trace_endpos + v_forward*4, self, 30);
};




//=============================================================================


void() GrenadeExplode =
{
	T_RadiusDamage (self, self.owner, 120, world);

//Damn, more sparks
//        WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
//        WriteByte (MSG_BROADCAST, TE_EXPLOSION);
//        WriteCoord (MSG_BROADCAST, self.origin_x);
//        WriteCoord (MSG_BROADCAST, self.origin_y);
//        WriteCoord (MSG_BROADCAST, self.origin_z);

	BecomeExplosion ();
};

void() GrenadeTouch =
{
	if (other == self.owner)
		return;		// don't explode on owner
	if (other.takedamage == DAMAGE_AIM)
	{
		GrenadeExplode();
		return;
	}
	sound (self, CHAN_WEAPON, "weapons/bounce.wav", 1, ATTN_NORM);	// bounce sound
	if (self.velocity == '0 0 0')
		self.avelocity = '0 0 0';
};

/*
================
W_FireGrenade
================
*/
void() W_FireGrenade =
{
	local	entity missile, mpuff;
	
	self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
	
	sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);

	self.punchangle_x = -2;

	missile = spawn ();
	missile.owner = self;
	missile.movetype = MOVETYPE_BOUNCE;
	missile.solid = SOLID_BBOX;
	missile.classname = "grenade";
		
// set missile speed	

	makevectors (self.v_angle);

	if (self.v_angle_x)
		missile.velocity = v_forward*600 + v_up * 200 + crandom()*v_right*10 + crandom()*v_up*10;
	else
	{
		missile.velocity = aim(self, 10000);
		missile.velocity = missile.velocity * 600;
		missile.velocity_z = 200;
	}

	missile.avelocity = '300 300 300';

	missile.angles = vectoangles(missile.velocity);
	
	missile.touch = GrenadeTouch;
	
// set missile duration
	missile.nextthink = time + 2.5;
	missile.think = GrenadeExplode;

//Cool, a dog head is gonna blow up soon!!
        setmodel (missile, "progs/h_dog.mdl");
	setsize (missile, '0 0 0', '0 0 0');		
	setorigin (missile, self.origin);
        Recoil (self,12);  //Pretty nice recoil huh?
};


//=============================================================================

void() spike_touch;
void() superspike_touch;
void (vector org) spawn_tfog;
void(entity me)     CameraOn;
void(entity me)     CameraOff;

void() hologram_explode =
{
    if (camera_on >= 1)  //Check to see if the camera is on.
      {
        camera_on = 0;              //Set the camera_on variable to 0 for off
        CameraOff( hologram.owner); //and turn the camera off.
       }

        makevectors(hologram.angles);
        spawn_tfog (hologram.origin + v_forward*20);
//        sound (self, CHAN_WEAPON, "misc/r_tele5.wav", 1, ATTN_NORM);
        remove(hologram);          //Remove the hologram
        jb_counter = 0;            //and set the jb_counter to 0 so that
                                   //the player can re-activate the
                                   //hologram.
};

/*
=======================
holo_touch
spawns tfog and plays a sound now.
=======================
*/
void() holo_touch =
{
        makevectors(self.angles);
        spawn_tfog (self.origin + v_forward*20);
//        sound (self, CHAN_WEAPON, "misc/r_tele5.wav", 1, ATTN_NORM);

};

void() holo_i =
{
        jb_counter = jb_counter + 1;
        if (jb_counter >= 300)      //Check if it time to self-terminate
                                    //the hologram program.
          {
           hologram_explode();
           sprint (hologram.owner,"Hologram shutdown...\n");
          }
	else
	{
	 hologram.frame = hologram.frame + 1;
	 if (hologram.frame < 12 || hologram.frame > 16)
        	hologram.frame = 12;
         hologram.skin = hologram.owner.skin;
         hologram.colormap = hologram.owner.colormap;
         hologram.nextthink = time + 0.1;
         hologram.think = holo_i;
	}
};
/*
===============
launch_hologram

By Jason Busby
===============
*/
void(vector org, vector dir) launch_hologram =
{
   if ((jb_counter > 0) && (hologram.owner == self))
      {
        sprint (self,"The hologram is already running.\n");
        return;
      }
	jb_counter = 1;
	hologram = spawn ();
	hologram.owner = self;
        hologram.flags = FL_ITEM;
        hologram.movetype = MOVETYPE_STEP;
        hologram.solid = SOLID_TRIGGER;
	hologram.angles = vectoangles(dir);
        hologram.touch = holo_touch;
        hologram.classname = "hologram";  //This is very important so that
                                          //later on you can refer to the
                                          //entity as a "hologram"
        hologram.think = holo_i;          //This is the start of the
                                          //bobbing up and down.
        hologram.nextthink = time + 1;
        setmodel (hologram, "progs/player.mdl");
	hologram.skin = self.skin;
	hologram.colormap = self.colormap;
        setsize (hologram, '-16 -16 -24', '16 16 40');
	setorigin (hologram, org);
	hologram.velocity = dir * 10;
        hologram.frame = 13;  //Once the mdl file is displayed, I use
                              //this to tell which frame to display
        sprint (self, "Hologram launched...\n");
};

void(float ox) W_FireHologram =      //Used to setup and launch the HOLOGRAM
{

	local vector    dir;
	local entity    old;
	
	makevectors (self.v_angle);
	
//        sound (self, CHAN_WEAPON, "misc/r_tele5.wav", 1, ATTN_NORM);
	self.attack_finished = time + 0.5;
	dir = aim (self, 1000);
        launch_hologram (self.origin + '0 0 24' + v_right*ox, dir);

//	self.punchangle_x = -2; // Don't think this is necessary
};
//==========================================================================


/*
===============
launch_spike

Used for both the player and the ogre
===============
*/
void(vector org, vector dir) launch_spike =
{
	newmis = spawn ();
	newmis.owner = self;
	newmis.movetype = MOVETYPE_FLYMISSILE;
	newmis.solid = SOLID_BBOX;

	newmis.angles = vectoangles(dir);
	
	newmis.touch = spike_touch;
	newmis.classname = "spike";
	newmis.think = SUB_Remove;
	newmis.nextthink = time + 6;
	setmodel (newmis, "progs/spike.mdl");
	setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);		
	setorigin (newmis, org);

	newmis.velocity = dir * 1000;
};

void() W_FireSuperSpikes =
{
	local vector	dir;
	local entity	old;
	
	sound (self, CHAN_WEAPON, "weapons/spike2.wav", 1, ATTN_NORM);
	self.attack_finished = time + 0.2;
	self.currentammo = self.ammo_nails = self.ammo_nails - 2;
	dir = aim (self, 1000);
	launch_spike (self.origin + '0 0 16', dir);
	newmis.touch = superspike_touch;
	setmodel (newmis, "progs/s_spike.mdl");
	setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);		
	self.punchangle_x = -2;
        Recoil (self,5);        //Just hold that attack button down
};

void(float ox) W_FireSpikes =
{
	local vector	dir;
	local entity	old;
	
	makevectors (self.v_angle);
	
	if (self.ammo_nails >= 2 && self.weapon == IT_SUPER_NAILGUN)
	{
		W_FireSuperSpikes ();
		return;
	}

	if (self.ammo_nails < 1)
	{
		self.weapon = W_BestWeapon ();
		W_SetCurrentAmmo ();
		return;
	}

	sound (self, CHAN_WEAPON, "weapons/rocket1i.wav", 1, ATTN_NORM);
	self.attack_finished = time + 0.2;
	self.currentammo = self.ammo_nails = self.ammo_nails - 1;
	dir = aim (self, 1000);
	launch_spike (self.origin + '0 0 16' + v_right*ox, dir);

	self.punchangle_x = -2;
        Recoil (self,2);   //Seems small now, go to E1M8
};



.float hit_z;
void() spike_touch =
{
local float rand;
	if (other == self.owner)
		return;

	if (other.solid == SOLID_TRIGGER)
		return;	// trigger field, do nothing

	if (pointcontents(self.origin) == CONTENT_SKY)
	{
		remove(self);
		return;
	}
	
// hit something that bleeds
	if (other.takedamage)
	{
		spawn_touchblood (9);
		T_Damage (other, self, self.owner, 9);
	}
	else
	{
		WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
		
		if (self.classname == "wizspike")
			WriteByte (MSG_BROADCAST, TE_WIZSPIKE);
		else if (self.classname == "knightspike")
			WriteByte (MSG_BROADCAST, TE_KNIGHTSPIKE);
		else
			WriteByte (MSG_BROADCAST, TE_SPIKE);
		WriteCoord (MSG_BROADCAST, self.origin_x);
		WriteCoord (MSG_BROADCAST, self.origin_y);
		WriteCoord (MSG_BROADCAST, self.origin_z);
	}

	remove(self);

};

void() superspike_touch =
{
local float rand;
	if (other == self.owner)
		return;

	if (other.solid == SOLID_TRIGGER)
		return;	// trigger field, do nothing

	if (pointcontents(self.origin) == CONTENT_SKY)
	{
		remove(self);
		return;
	}
	
// hit something that bleeds
	if (other.takedamage)
	{
		spawn_touchblood (18);
		T_Damage (other, self, self.owner, 18);
	}
	else
	{
		WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
		WriteByte (MSG_BROADCAST, TE_SUPERSPIKE);
		WriteCoord (MSG_BROADCAST, self.origin_x);
		WriteCoord (MSG_BROADCAST, self.origin_y);
		WriteCoord (MSG_BROADCAST, self.origin_z);
	}

	remove(self);

};

/*
=========================================================================
Flares Code Begins Here.
=========================================================================
*/

/*
============================
flare_touch

rework of id's spike_touch()
============================
*/
void() flare_touch =
{
local float rand;
	if (other == self.owner)
		return;

        if (other.classname == "door" || other.classname == "plat")
                {
                remove(self);
                return;
                }

	if (other.solid == SOLID_TRIGGER)
		return; // trigger field, do nothing

	if (pointcontents(self.origin) == CONTENT_SKY)
	{
		remove(self);
		return;
	}
	
// has the flare hit something that bleeds?
	if (other.takedamage)
	{
                // If so, spawn some blood
		spawn_touchblood (9);
                // also do one point of damage    
		T_Damage (other, self, self.owner, 1);

/*
Don't remove the flare unless it is still flying. Otherwise, monsters or
other players can come up and 'pull' your flare out of the wall
*/
	      if (self.velocity != '0 0 0')
			remove(self);
	}
	else
	{
        // Write information to the network
		WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
		WriteByte (MSG_BROADCAST, TE_SPIKE);
		WriteCoord (MSG_BROADCAST, self.origin_x);
		WriteCoord (MSG_BROADCAST, self.origin_y);
		WriteCoord (MSG_BROADCAST, self.origin_z);
	}

//Stop the flare, but do not remove it.
	self.movetype = MOVETYPE_NONE;
// Fix it so that flare only partially embeds itself (thanks, Luke)
        self.origin = self.origin - self.velocity * 0.005;
     	self.velocity = '0 0 0';
	self.touch = SUB_Null;
};
/*
==============================
flare_dim()

This function makes the flare
go dim again
==============================
*/
void() flare_dim =
{
// Make the flare get dim by setting .effects bit        
        self.effects=EF_DIMLIGHT;
// Give it 15 seconds before burnout
	self.nextthink = time + 15;
// After 15 seconds remove the flare from the game
	self.think = SUB_Remove;
};



/*
==============================
flare_bright()

This function makes the flare
emit brighter light
==============================
*/

void() flare_bright =
{
	local vector    vel;
// Make the flare get BRIGHT by setting .effects bit       
        self.effects=EF_BRIGHTLIGHT;
// Give it 10 seconds at maximum intensity
	self.nextthink = time + 10;
// After 10 seconds, call flare_dim
	self.think = flare_dim;
// Play a sound for flare ignition
	sound (self, CHAN_WEAPON, "misc/power.wav", 1, ATTN_NORM);
	
// Set up some red and yellow sparks
	vel = '0 0 150';
	particle (self.origin+vel*0.01,vel,111,150);
        vel = '0 0 120';
	particle (self.origin+vel*0.01,vel,73,200);


};

/*
================================
launch_flare

rework of id's launch_spike code
================================
*/
void(vector org, vector dir) launch_flare =
{
	local   entity  missile;

	missile = spawn ();
	missile.owner = self;
	missile.movetype = MOVETYPE_FLYMISSILE;
	missile.solid = SOLID_BBOX;

	missile.angles = vectoangles(dir);
	
// go to flare_touch if the flare touches anything
	missile.touch = flare_touch;
        missile.classname = "flare";

// go to flare_bright when the flare's think time is up
	missile.think = flare_bright;

// 3 seconds until flare goes bright
	missile.nextthink = time + 3;

// The LASER.MDL makes a decent flare
	setmodel (missile, "progs/laser.mdl");
	setsize (missile, VEC_ORIGIN, VEC_ORIGIN);               
	setorigin (missile, org);
	missile.velocity = dir * 1000;

// Make the flare dim. (.effects is an 8-bit register)
        missile.effects=EF_DIMLIGHT;

};

void() W_FireFlare =
{
        local vector org,dir;
        
        self.attack_finished = time + 0.5;
        makevectors (self.v_angle);
        org = self.origin + v_forward * 7.5 + '0 0 16';
        dir = aim (self, 1800);
        launch_flare(org, dir);
	self.punchangle_x = -2;
};

/*
===================================================================
End of Flare Code  -    Steve Bond 8/1/96
===================================================================
*/
/*
 ------------------------------------------
 Pipe Bombs
 ------------------------------------------
*/

/*
 * Blow up the toys.  There is a range of 1000 units (pixels?), so you can't
 * go wandering off.
 */
 
void() DetPipeBombs =
{
        local entity    head;

        head = findradius (self.origin, 1000);
        if (head)
             sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
        while(head)
        {
                if((head.classname == "pipebomb") && (head.owner == self))
                        head.nextthink = time;
                head = head.chain;
        }
};

/*
 * What happens if it touches something
 */
 
void() PipeBombTouch =
{
	if (other == self.owner)
		return;		// don't explode on owner
	sound (self, CHAN_WEAPON, "weapons/bounce.wav", 1, ATTN_NORM);	// bounce sound
	if (self.velocity == '0 0 0')
		self.avelocity = '0 0 0';
};

/*
 * Fires a pipe bomb.  Can be detonated at any time.  Doesn't need a special
 * weapon selected.
 */

void() W_FirePipeBomb =
{
	local	entity missile, mpuff;
	
	if(self.ammo_rockets < 1)	// have to have ammo
	  return;
	self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
        self.flags = self.flags | FL_ATTACKED; //says that you have attacked for teamplay
	
        sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
   
        self.punchangle_x = -2;

	missile = spawn ();
	missile.owner = self;
	missile.movetype = MOVETYPE_BOUNCE;
	missile.solid = SOLID_BBOX;
	missile.classname = "pipebomb";
		
// set missile speed	

	makevectors (self.v_angle);

	if (self.v_angle_x)
		missile.velocity = v_forward*600 + v_up * 200 + crandom()*v_right*10 + crandom()*v_up*10;
	else
	{
		missile.velocity = aim(self, 10000);
		missile.velocity = missile.velocity * 600;
		missile.velocity_z = 200;
	}

	missile.avelocity = '300 300 300';

	missile.angles = vectoangles(missile.velocity);
	
	missile.touch = PipeBombTouch;
	missile.think = GrenadeExplode;
	
	setmodel (missile, "progs/grenade.mdl");
	setsize (missile, '0 0 0', '0 0 0');		
	setorigin (missile, self.origin);
};

/*
===============================================================================

PLAYER WEAPON USE

===============================================================================
*/

void() W_SetCurrentAmmo =
{
 if(self.classname != "player")
   return;
	player_run ();		// get out of any weapon firing states

	self.items = self.items - ( self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS) );
	
	if (self.weapon == IT_AXE)
	{
		self.currentammo = 0;
		self.weaponmodel = "progs/v_axe.mdl";
		self.weaponframe = 0;
	}
      else if (self.weapon == IT_THROWING_AXE)
	{
                self.currentammo = self.num_axes;
		self.weaponmodel = "progs/v_axe.mdl";
		self.weaponframe = 0;
                
	}
	else if (self.weapon == IT_SHOTGUN)
	{
		self.currentammo = self.ammo_shells;
		self.weaponmodel = "progs/v_shot.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_SHELLS;
	}
	else if (self.weapon == IT_SUPER_SHOTGUN)
	{
		self.currentammo = self.ammo_shells;
		self.weaponmodel = "progs/v_shot2.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_SHELLS;
	}
	else if (self.weapon == IT_NAILGUN)
	{
		self.currentammo = self.ammo_nails;
		self.weaponmodel = "progs/v_nail.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_NAILS;
	}
	else if (self.weapon == IT_SUPER_NAILGUN)
	{
		self.currentammo = self.ammo_nails;
		self.weaponmodel = "progs/v_nail2.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_NAILS;
	}
	else if (self.weapon == IT_GRENADE_LAUNCHER)
	{
		self.currentammo = self.ammo_rockets;
		self.weaponmodel = "progs/v_rock.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_ROCKETS;
	}
	else if (self.weapon == IT_ROCKET_LAUNCHER)
	{
		self.currentammo = self.ammo_rockets;
		self.weaponmodel = "progs/v_rock2.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_ROCKETS;
	}
	else if (self.weapon == IT_LIGHTNING)
	{
		self.currentammo = self.ammo_cells;
		self.weaponmodel = "progs/v_light.mdl";
		self.weaponframe = 0;
		self.items = self.items | IT_CELLS;
	}
	else
	{
		self.currentammo = 0;
		self.weaponmodel = "";
		self.weaponframe = 0;
	}
};

float() W_BestWeapon =
{
	local	float	it;
	
	it = self.items;

/*added the check to see if you are in water so you don't switch to this
  in the middle of an underwater battle.  Man that sucks.
*/
        if(self.ammo_cells >= 1 && (it & IT_LIGHTNING) && (self.waterlevel <= 1))
		return IT_LIGHTNING;
	else if(self.ammo_nails >= 2 && (it & IT_SUPER_NAILGUN) )
		return IT_SUPER_NAILGUN;
	else if(self.ammo_shells >= 2 && (it & IT_SUPER_SHOTGUN) )
		return IT_SUPER_SHOTGUN;
	else if(self.ammo_nails >= 1 && (it & IT_NAILGUN) )
		return IT_NAILGUN;
	else if(self.ammo_shells >= 1 && (it & IT_SHOTGUN) )
		return IT_SHOTGUN;
		
/*
	if(self.ammo_rockets >= 1 && (it & IT_ROCKET_LAUNCHER) )
		return IT_ROCKET_LAUNCHER;
	else if(self.ammo_rockets >= 1 && (it & IT_GRENADE_LAUNCHER) )
		return IT_GRENADE_LAUNCHER;

*/

	return IT_AXE;
};

float() W_CheckNoAmmo =
{
	if (self.currentammo > 0)
		return TRUE;

	if (self.weapon == IT_AXE)
		return TRUE;
	
	self.weapon = W_BestWeapon ();

	W_SetCurrentAmmo ();
	
// drop the weapon down
	return FALSE;
};

/*
============
W_Attack

An attack impulse can be triggered now
============
*/
void()	player_axe1;
void()	player_axeb1;
void()	player_axec1;
void()	player_axed1;
void()	player_shot1;
void()	player_nail1;
void()	player_light1;
void()	player_rocket1;

void() W_Attack =
{
	local	float	r;

	if (!W_CheckNoAmmo ())
		return;

	makevectors	(self.v_angle);			// calculate forward angle for velocity
	self.show_hostile = time + 1;	// wake monsters up
        self.flags = self.flags | FL_ATTACKED; //says that you have attacked for teamplay

	if (self.weapon == IT_AXE)
	{
		sound (self, CHAN_WEAPON, "weapons/ax1.wav", 1, ATTN_NORM);
		r = random();
		if (r < 0.25)
			player_axe1 ();
		else if (r<0.5)
			player_axeb1 ();
		else if (r<0.75)
			player_axec1 ();
		else
			player_axed1 ();
		self.attack_finished = time + 0.5;
	}
      else if (self.weapon == IT_THROWING_AXE)
	{
                player_tax1 ();

                self.attack_finished = time + 1;
	}
	else if (self.weapon == IT_SHOTGUN)
	{
		player_shot1 ();
		W_FireShotgun ();
		self.attack_finished = time + 0.5;
	}
	else if (self.weapon == IT_SUPER_SHOTGUN)
	{
		player_shot1 ();
		W_FireSuperShotgun ();
		self.attack_finished = time + 0.7;
	}
	else if (self.weapon == IT_NAILGUN)
	{
		player_nail1 ();
	}
	else if (self.weapon == IT_SUPER_NAILGUN)
	{
		player_nail1 ();
	}
	else if (self.weapon == IT_GRENADE_LAUNCHER)
	{
		player_rocket1();
		W_FireGrenade();
		self.attack_finished = time + 0.6;
	}
	else if (self.weapon == IT_ROCKET_LAUNCHER)
	{
		player_rocket1();
		W_FireRocket();
		self.attack_finished = time + 0.8;
	}
	else if (self.weapon == IT_LIGHTNING)
	{
		player_light1();
		self.attack_finished = time + 0.1;
		sound (self, CHAN_AUTO, "weapons/lstart.wav", 1, ATTN_NORM);
	}
};

/*
============
W_ChangeWeapon

============
*/
void() W_ChangeWeapon =
{
	local	float	it, am, fl;
 
	it = self.items;
	am = 0;
	
	if (self.impulse == 1)
	{
                if (self.weapon == IT_AXE)
                {
                        sprint(self,"Throwing Axe!\n");
                        fl=IT_THROWING_AXE;
                        if (self.num_axes <1)
                                am = 1;
                }
                else
                {
                        sprint(self,"Normal Axe!\n");
                        fl = IT_AXE;
                }                
	}
	else if (self.impulse == 2)
	{
		fl = IT_SHOTGUN;
		if (self.ammo_shells < 1)
			am = 1;
	}
	else if (self.impulse == 3)
	{
		fl = IT_SUPER_SHOTGUN;
		if (self.ammo_shells < 2)
			am = 1;
	}		
	else if (self.impulse == 4)
	{
		fl = IT_NAILGUN;
		if (self.ammo_nails < 1)
			am = 1;
	}
	else if (self.impulse == 5)
	{
		fl = IT_SUPER_NAILGUN;
		if (self.ammo_nails < 2)
			am = 1;
	}
	else if (self.impulse == 6)
	{
		fl = IT_GRENADE_LAUNCHER;
		if (self.ammo_rockets < 1)
			am = 1;
	}
	else if (self.impulse == 7)
	{
		fl = IT_ROCKET_LAUNCHER;
		if (self.ammo_rockets < 1)
			am = 1;
	}
	else if (self.impulse == 8)
	{
		fl = IT_LIGHTNING;
		if (self.ammo_cells < 1)
			am = 1;
	}

	self.impulse = 0;
	
	if (!(self.items & fl))
	{	// don't have the weapon or the ammo
		sprint (self, "no weapon.\n");
		return;
	}
	
	if (am)
	{	// don't have the ammo
		sprint (self, "not enough ammo.\n");
		return;
	}

//
// set weapon, set ammo
//
	self.weapon = fl;		
	W_SetCurrentAmmo ();
};

/*
============
CheatCommand
============
*/
void() CheatCommand =
{
	if (deathmatch || coop)
		return;

	self.ammo_rockets = 100;
	self.ammo_nails = 200;
	self.ammo_shells = 100;
	self.num_axes = 100;
	self.items = self.items | 
		IT_AXE |
		IT_SHOTGUN |
		IT_SUPER_SHOTGUN |
		IT_NAILGUN |
		IT_SUPER_NAILGUN |
		IT_GRENADE_LAUNCHER |
		IT_ROCKET_LAUNCHER |
		IT_KEY1 | IT_KEY2;

	self.ammo_cells = 200;
	self.items = self.items | IT_LIGHTNING;

	self.weapon = IT_ROCKET_LAUNCHER;
	self.impulse = 0;
	W_SetCurrentAmmo ();
};

/*
============
CycleWeaponCommand

Go to the next weapon with ammo
============
*/
void() CycleWeaponCommand =
{
	local	float	it, am;
	
	it = self.items;
	self.impulse = 0;
	
	while (1)
	{
		am = 0;

		if (self.weapon == IT_LIGHTNING)
		{
			self.weapon = IT_AXE;
		}
                else if (self.weapon == IT_AXE || self.weapon == IT_THROWING_AXE)
		{
			self.weapon = IT_SHOTGUN;
			if (self.ammo_shells < 1)
				am = 1;
		}
		else if (self.weapon == IT_SHOTGUN)
		{
			self.weapon = IT_SUPER_SHOTGUN;
			if (self.ammo_shells < 2)
				am = 1;
		}		
		else if (self.weapon == IT_SUPER_SHOTGUN)
		{
			self.weapon = IT_NAILGUN;
			if (self.ammo_nails < 1)
				am = 1;
		}
		else if (self.weapon == IT_NAILGUN)
		{
			self.weapon = IT_SUPER_NAILGUN;
			if (self.ammo_nails < 2)
				am = 1;
		}
		else if (self.weapon == IT_SUPER_NAILGUN)
		{
			self.weapon = IT_GRENADE_LAUNCHER;
			if (self.ammo_rockets < 1)
				am = 1;
		}
		else if (self.weapon == IT_GRENADE_LAUNCHER)
		{
			self.weapon = IT_ROCKET_LAUNCHER;
			if (self.ammo_rockets < 1)
				am = 1;
		}
		else if (self.weapon == IT_ROCKET_LAUNCHER)
		{
			self.weapon = IT_LIGHTNING;
			if (self.ammo_cells < 1)
				am = 1;
		}
	
		if ( (self.items & self.weapon) && am == 0)
		{
			W_SetCurrentAmmo ();
			return;
		}
	}

};

/*
============
ServerflagsCommand

Just for development
============
*/
void() ServerflagsCommand =
{
	serverflags = serverflags * 2 + 1;
};

void() QuadCheat =
{
	if (deathmatch || coop)
		return;
	self.super_time = 1;
	self.super_damage_finished = time + 30;
	self.items = self.items | IT_QUAD;
	dprint ("quad cheat\n");
};

/*Thank you VHOLD for the backpack code, and whoever else did the
  exploding backpack thing.  Watch out though, these things don't
  react too well to bullets.
*/

void() backpack_explode;
void() ThrowBackpack =
{
	local entity 	item;

	if ( (self.ammo_shells + self.ammo_nails + self.ammo_rockets + self.ammo_cells) == 0)
		return;

	item = spawn();

        if ( self.ammo_shells >= 20)
	{
		item.ammo_shells = 20;
		self.ammo_shells = self.ammo_shells - 20;
	}
	else
	{
		item.ammo_shells = self.ammo_shells;
		self.ammo_shells = 0;
	}
	
        if ( self.ammo_nails >= 20)
	{
		item.ammo_nails = 20;
                self.ammo_nails = self.ammo_nails - 20;
	}
	else
	{
		item.ammo_nails = self.ammo_nails;
		self.ammo_nails = 0;
	}

	if ( self.ammo_rockets >= 10)
	{
		item.ammo_rockets = 10;
		self.ammo_rockets = self.ammo_rockets - 10;
	}
	else
	{
		item.ammo_rockets = self.ammo_rockets;
                self.ammo_rockets = 0;
	}

	if (self.ammo_cells >= 20)
	{	
		item.ammo_cells = 20;
		self.ammo_cells = self.ammo_cells - 20;
	}
	else
	{
		item.ammo_cells = self.ammo_cells;
		self.ammo_cells = 0;
	}

	makevectors(self.v_angle);
	item.velocity = aim(self, 1000);
        item.velocity = 500 * item.velocity;
        setorigin(item, self.origin + '0 0 40');

	item.flags = FL_ITEM;
        item.solid = SOLID_SLIDEBOX;
        item.movetype = MOVETYPE_TOSS;
        setmodel (item, "progs/backpack.mdl");
        setsize(item, '-16 -16 0', '16 16 56');
	item.touch = BackpackTouch;

// If the pack has rockets, you can blow this puppy up
        if (item.ammo_rockets)
        {
                item.health = 30;
                item.th_die = backpack_explode;
                item.takedamage = DAMAGE_AIM;
        }
        else
                item.takedamage = DAMAGE_NO;

	item.nextthink = time + 120;	// remove after 2 minutes
        item.think = SUB_Remove;

	W_SetCurrentAmmo();
};


/*
============
ImpulseCommands

============
*/
void() ImpulseCommands =
{
        if (self.impulse == 150)
        {
            feign ();
            self.impulse = 0;
        }

        if (self.flags & FL_ISFEIGN)
             return;

	if (self.impulse >= 1 && self.impulse <= 8)
		W_ChangeWeapon ();

	if (self.impulse == 9)
		CheatCommand ();
	if (self.impulse == 10)
		CycleWeaponCommand ();
	if (self.impulse == 11)
		ServerflagsCommand ();

//Gotta have it
	if (self.impulse == 20)
		ThrowBackpack();

      if (self.impulse == 30)
            W_FireFlare ();  

//===========================================================================
        if (self.impulse == 31)  // Activate/Deactivate hologram
         {
            if (jb_counter <= 0)
                 W_FireHologram ();
             else
               {
                 if (hologram.owner == self)
                    hologram_explode();
                 sprint (self, "Hologram off...\n");
                 jb_counter = 0;
               }
         }


        if (self.impulse == 33)  // Use for right turning of hologram
         {
           if (jb_counter > 0)
               hologram.angles_y = hologram.angles_y - 5;
          }

        if (self.impulse == 34)  // Use for left turning of hologram
         {
           if (jb_counter > 0)
               hologram.angles_y = hologram.angles_y + 5;
         }

        // New impulse 36 = Camera
                if (self.impulse == 36)
                 {
                     if (jb_counter <=0)
                      
                        sprint (self,"Hologram must be activated first...\n");

                     else

                      if (camera_on <= 0)
                       {
                         camera_on = 1;
                         CameraOn( self);
                       }
                       else
                       {
                         camera_on = 0;
                         CameraOff( self);  //NezuCamera( self);
                       }
                 }
//===========================================================================

      if(self.impulse == 61)
            W_FirePipeBomb();

      if(self.impulse == 62)
            DetPipeBombs();

// Big thanks goes to Dennis for this one.  A dream come true.
// ********************************************************************* //
// **								      ** //
// **  MULTISKIN 1.1 ADDED SECTION				      ** //
// **								      ** //
// ********************************************************************* //	


	if ((self.impulse == 200) || (self.impulse == 201))
	{
        //Just try to change teams in the middle of play
                if ( (self.flags & FL_ATTACKED) && (teamplay) )
                {
                        self.classname = "skinchange";
                        T_Damage (self, self, self, 50000);
                        return;
                }else if (self.impulse == 200)
		{
                        self.skin = self.skin + 1;
                        if (self.skin == 32) self.skin = 0;
                } else if (self.impulse == 201)
		{
                        self.skin = self.skin - 1;
                        if (self.skin == -1) self.skin = 31;
		}
                if (self.skin == 0) sprint(self, "SKIN: Quake himself (1)\n"); else
                if (self.skin == 1) sprint(self, "SKIN: Duke Nukem 3d (2)\n"); else
                if (self.skin == 2) sprint(self, "SKIN: Mr. Toad (3)\n"); else
                if (self.skin == 3) sprint(self, "SKIN: the Stormtrooper (4)\n"); else
                if (self.skin == 4) sprint(self, "SKIN: Max (5)\n"); else
                if (self.skin == 5) sprint(self, "SKIN: the Terminator (6)\n"); else
                if (self.skin == 6) sprint(self, "SKIN: Judge Dredd (7)\n"); else
                if (self.skin == 7) sprint(self, "SKIN: Camouflaged soldier (8)\n"); else
                if (self.skin == 8) sprint(self, "SKIN: Captain Picard (9)\n"); else
                if (self.skin == 9) sprint(self, "SKIN: the Wizzard (10)\n"); else
                if (self.skin == 10) sprint(self,"SKIN: the Predator (11)\n"); else
                if (self.skin == 11) sprint(self,"SKIN: Skeleton (12)\n"); else
                if (self.skin == 12) sprint(self,"SKIN: Wan-Fu (13)\n"); else
                if (self.skin == 13) sprint(self,"SKIN: Henry Rollins (14)\n"); else
                if (self.skin == 14) sprint(self,"SKIN: He-Man (15)\n"); else
                if (self.skin == 15) sprint(self,"SKIN: Boba (16)\n"); else
                if (self.skin == 16) sprint(self,"SKIN: Superman (17)\n"); else
                if (self.skin == 17) sprint(self,"SKIN: NYPD Cop (18)\n"); else
                if (self.skin == 18) sprint(self,"SKIN: Avatar (19)\n"); else
                if (self.skin == 19) sprint(self, "SKIN: C-3PO (20)\n"); else
                if (self.skin == 20) sprint(self,"SKIN: Han Solo (21)\n"); else
                if (self.skin == 21) sprint(self,"SKIN: Ninja (22)\n"); else
                if (self.skin == 22) sprint(self,"SKIN: Jason (23)\n"); else
                if (self.skin == 23) sprint(self,"SKIN: The Evil Eye (24)\n"); else
                if (self.skin == 24) sprint(self,"SKIN: MoleMan (25)\n"); else
                if (self.skin == 25) sprint(self,"SKIN: Mr. Rage (26)\n"); else
                if (self.skin == 26) sprint(self,"SKIN: The Flash (27)\n"); else
                if (self.skin == 27) sprint(self,"SKIN: Striper (28)\n"); else
                if (self.skin == 28) sprint(self,"SKIN: Bat Man (19)\n"); else
                if (self.skin == 29) sprint(self, "SKIN: Bossk (20)\n"); else
                if (self.skin == 30) sprint(self,"SKIN: Spider Man (21)\n"); else
                if (self.skin == 31) sprint(self,"SKIN: BioMan (22)\n"); 
	}

// ********************************************************************* //
// **								      ** //
// **  MULTISKIN 1.1 END OF ADDED SECTION 			      ** //
// **								      ** //
// ********************************************************************* //	


      if (self.impulse == 255)
            QuadCheat ();

      self.impulse = 0;
};

/*
============
W_WeaponFrame

Called every frame so impulse events can be handled as well as possible
============
*/
void() W_WeaponFrame =
{
	if (time < self.attack_finished)
		return;

	ImpulseCommands ();
	
// check for attack
	if (self.button0)
	{
		SuperDamageSound ();
		W_Attack ();
	}
};

/*
========
SuperDamageSound

Plays sound if needed
========
*/
void() SuperDamageSound =
{
	if (self.super_damage_finished > time)
	{
		if (self.super_sound < time)
		{
			self.super_sound = time + 1;
			sound (self, CHAN_BODY, "items/damage3.wav", 1, ATTN_NORM);
		}
	}
	return;
};
